Introduce instance ICS & Atom feeds (disabled by default)

And refactor the feed modules

Signed-off-by: Thomas Citharel <tcit@tcit.fr>

lib/service/export/common.ex

@@ -0,0 +1,77 @@
+defmodule Mobilizon.Service.Export.Common do
+  @moduledoc """
+  Common tools for exportation
+  """
+
+  alias Mobilizon.{Actors, Events, Posts, Users}
+  alias Mobilizon.Actors.Actor
+  alias Mobilizon.Events.{Event, FeedToken}
+  alias Mobilizon.Storage.Page
+  alias Mobilizon.Users.User
+
+  @spec fetch_actor_event_feed(String.t()) :: String.t()
+  def fetch_actor_event_feed(name) do
+    with %Actor{} = actor <- Actors.get_local_actor_by_name(name),
+         {:visibility, true} <- {:visibility, Actor.is_public_visibility?(actor)},
+         %Page{elements: events} <- Events.list_public_events_for_actor(actor),
+         %Page{elements: posts} <- Posts.get_public_posts_for_group(actor) do
+      {:ok, actor, events, posts}
+    else
+      err ->
+        {:error, err}
+    end
+  end
+
+  # Only events, not posts
+  @spec fetch_events_from_token(String.t()) :: String.t()
+  def fetch_events_from_token(token) do
+    with {:ok, _uuid} <- Ecto.UUID.cast(token),
+         %FeedToken{actor: actor, user: %User{} = user} <- Events.get_feed_token(token) do
+      case actor do
+        %Actor{} = actor ->
+          %{
+            type: :actor,
+            actor: actor,
+            events: fetch_actor_private_events(actor),
+            user: user,
+            token: token
+          }
+
+        nil ->
+          with actors <- Users.get_actors_for_user(user),
+               events <-
+                 actors
+                 |> Enum.map(&fetch_actor_private_events/1)
+                 |> Enum.concat() do
+            %{type: :user, events: events, user: user, token: token, actor: nil}
+          end
+      end
+    end
+  end
+
+  @spec fetch_instance_public_content :: {:ok, list(Event.t()), list(Post.t())}
+  def fetch_instance_public_content do
+    with %Page{elements: events} <- Events.list_public_local_events(),
+         %Page{elements: posts} <- Posts.list_public_local_posts() do
+      {:ok, events, posts}
+    end
+  end
+
+  @spec fetch_actor_private_events(Actor.t()) :: list(Event.t())
+  def fetch_actor_private_events(%Actor{} = actor) do
+    actor |> fetch_identity_participations() |> participations_to_events()
+  end
+
+  @spec fetch_identity_participations(Actor.t()) :: Page.t()
+  defp fetch_identity_participations(%Actor{} = actor) do
+    with %Page{} = page <- Events.list_event_participations_for_actor(actor) do
+      page
+    end
+  end
+
+  defp participations_to_events(%Page{elements: participations}) do
+    participations
+    |> Enum.map(& &1.event_id)
+    |> Enum.map(&Events.get_event_with_preload!/1)
+  end
+end

lib/service/export/feed.ex

@@ -7,11 +7,11 @@ defmodule Mobilizon.Service.Export.Feed do
 
   alias Atomex.{Entry, Feed}
 
-  alias Mobilizon.{Actors, Config, Events, Posts, Users}
   alias Mobilizon.Actors.Actor
-  alias Mobilizon.Events.{Event, FeedToken}
+  alias Mobilizon.Config
+  alias Mobilizon.Events.Event
   alias Mobilizon.Posts.Post
-  alias Mobilizon.Storage.Page
+  alias Mobilizon.Service.Export.Common
   alias Mobilizon.Users.User
 
   alias Mobilizon.Web.Endpoint
@@ -43,14 +43,57 @@ defmodule Mobilizon.Service.Export.Feed do
     end
   end
 
+  def create_cache("instance") do
+    case fetch_instance_feed() do
+      {:ok, res} ->
+        {:commit, res}
+
+      err ->
+        {:ignore, err}
+    end
+  end
+
+  @spec fetch_instance_feed :: {:ok, String.t()}
+  defp fetch_instance_feed do
+    case Common.fetch_instance_public_content() do
+      {:ok, events, posts} ->
+        {:ok, build_instance_feed(events, posts)}
+
+      err ->
+        {:error, err}
+    end
+  end
+
+  # Build an atom feed from the whole instance and its public events and posts
+  @spec build_instance_feed(list(), list()) :: String.t()
+  defp build_instance_feed(events, posts) do
+    self_url = Endpoint.url()
+
+    title =
+      gettext("Public feed for %{instance}",
+        instance: Config.instance_name()
+      )
+
+    # Title uses default instance language
+    self_url
+    |> Feed.new(
+      DateTime.utc_now(),
+      title
+    )
+    |> Feed.link(self_url, rel: "self")
+    |> Feed.link(self_url, rel: "alternate")
+    |> Feed.generator(Config.instance_name(), uri: Endpoint.url(), version: version())
+    |> Feed.entries(Enum.map(events ++ posts, &get_entry/1))
+    |> Feed.build()
+    |> Atomex.generate_document()
+  end
+
   @spec fetch_actor_event_feed(String.t()) :: String.t()
   defp fetch_actor_event_feed(name) do
-    with %Actor{} = actor <- Actors.get_local_actor_by_name(name),
-         {:visibility, true} <- {:visibility, Actor.is_public_visibility?(actor)},
-         %Page{elements: events} <- Events.list_public_events_for_actor(actor),
-         %Page{elements: posts} <- Posts.get_public_posts_for_group(actor) do
-      {:ok, build_actor_feed(actor, events, posts)}
-    else
+    case Common.fetch_actor_event_feed(name) do
+      {:ok, actor, events, posts} ->
+        {:ok, build_actor_feed(actor, events, posts)}
+
       err ->
         {:error, err}
     end
@@ -156,41 +199,15 @@ defmodule Mobilizon.Service.Export.Feed do
   # Only events, not posts
   @spec fetch_events_from_token(String.t()) :: String.t()
   defp fetch_events_from_token(token) do
-    with {:ok, _uuid} <- Ecto.UUID.cast(token),
-         %FeedToken{actor: actor, user: %User{} = user} <- Events.get_feed_token(token) do
-      case actor do
-        %Actor{} = actor ->
-          events = actor |> fetch_identity_participations() |> participations_to_events()
-          {:ok, build_actor_feed(actor, events, [], false)}
-
-        nil ->
-          with actors <- Users.get_actors_for_user(user),
-               events <-
-                 actors
-                 |> Enum.map(fn actor ->
-                   actor
-                   |> Events.list_event_participations_for_actor()
-                   |> participations_to_events()
-                 end)
-                 |> Enum.concat() do
-            {:ok, build_user_feed(events, user, token)}
-          end
+    with %{events: events, token: token, user: user, actor: actor, type: type} <-
+           Common.fetch_events_from_token(token) do
+      case type do
+        :user -> {:ok, build_user_feed(events, user, token)}
+        :actor -> {:ok, build_actor_feed(actor, events, [], false)}
       end
     end
   end
 
-  defp fetch_identity_participations(%Actor{} = actor) do
-    with %Page{} = page <- Events.list_event_participations_for_actor(actor) do
-      page
-    end
-  end
-
-  defp participations_to_events(%Page{elements: participations}) do
-    participations
-    |> Enum.map(& &1.event_id)
-    |> Enum.map(&Events.get_event_with_preload!/1)
-  end
-
   # Build an atom feed from actor and its public events
   @spec build_user_feed(list(), User.t(), String.t()) :: String.t()
   defp build_user_feed(events, %User{email: email}, token) do

lib/service/export/icalendar.ex

@@ -3,83 +3,23 @@ defmodule Mobilizon.Service.Export.ICalendar do
   Export an event to iCalendar format.
   """
 
-  alias Mobilizon.{Actors, Config, Events, Users}
   alias Mobilizon.Actors.Actor
   alias Mobilizon.Addresses.Address
-  alias Mobilizon.Events.{Event, FeedToken}
+  alias Mobilizon.{Config, Events}
+  alias Mobilizon.Events.Event
+  alias Mobilizon.Service.Export.Common
   alias Mobilizon.Service.Formatter.HTML
-  alias Mobilizon.Storage.Page
-  alias Mobilizon.Users.User
 
   @vendor "Mobilizon #{Config.instance_version()}"
 
-  @doc """
-  Export a public event to iCalendar format.
-
-  The event must have a visibility of `:public` or `:unlisted`
-  """
-  @spec export_public_event(Event.t()) :: {:ok, String.t()}
-  def export_public_event(%Event{visibility: visibility} = event)
-      when visibility in [:public, :unlisted] do
-    export_event(event)
-  end
-
-  @spec export_public_event(Event.t()) :: {:error, :event_not_public}
-  def export_public_event(%Event{}), do: {:error, :event_not_public}
-
-  @doc """
-  Export an event to iCalendar format
-  """
-  def export_event(%Event{} = event) do
-    {:ok, %ICalendar{events: [do_export_event(event)]} |> ICalendar.to_ics(vendor: @vendor)}
-  end
-
-  @spec do_export_event(Event.t()) :: ICalendar.Event.t()
-  defp do_export_event(%Event{} = event) do
-    %ICalendar.Event{
-      summary: event.title,
-      dtstart: event.begins_on,
-      dtstamp: event.publish_at || DateTime.utc_now(),
-      dtend: event.ends_on,
-      description: HTML.strip_tags(event.description),
-      uid: event.uuid,
-      url: event.url,
-      geo: Address.coords(event.physical_address),
-      location: Address.representation(event.physical_address),
-      categories: event.tags |> Enum.map(& &1.title)
-    }
-  end
-
-  @doc """
-  Export a public actor's events to iCalendar format.
-
-  The actor must have a visibility of `:public` or `:unlisted`, as well as the events
-  """
-  @spec export_public_actor(Actor.t()) :: String.t()
-  def export_public_actor(%Actor{} = actor) do
-    with {:visibility, true} <- {:visibility, Actor.is_public_visibility?(actor)},
-         %Page{elements: events} <-
-           Events.list_public_events_for_actor(actor) do
-      {:ok, %ICalendar{events: events |> Enum.map(&do_export_event/1)} |> ICalendar.to_ics()}
-    end
-  end
-
-  @spec export_private_actor(Actor.t()) :: String.t()
-  def export_private_actor(%Actor{} = actor) do
-    with events <-
-           actor |> Events.list_event_participations_for_actor() |> participations_to_events() do
-      {:ok, %ICalendar{events: events |> Enum.map(&do_export_event/1)} |> ICalendar.to_ics()}
-    end
-  end
-
   @doc """
   Create cache for an actor, an event or an user token
   """
   def create_cache("actor_" <> name) do
-    with %Actor{} = actor <- Actors.get_local_actor_by_name(name),
-         {:ok, res} <- export_public_actor(actor) do
-      {:commit, res}
-    else
+    case export_public_actor(name) do
+      {:ok, res} ->
+        {:commit, res}
+
       err ->
         {:ignore, err}
     end
@@ -105,33 +45,96 @@ defmodule Mobilizon.Service.Export.ICalendar do
     end
   end
 
-  @spec fetch_events_from_token(String.t()) :: String.t()
-  defp fetch_events_from_token(token) do
-    with %FeedToken{actor: actor, user: %User{} = user} <- Events.get_feed_token(token) do
-      case actor do
-        %Actor{} = actor ->
-          export_private_actor(actor)
+  def create_cache("instance") do
+    case fetch_instance_feed() do
+      {:ok, res} ->
+        {:commit, res}
 
-        nil ->
-          with actors <- Users.get_actors_for_user(user),
-               events <-
-                 actors
-                 |> Enum.map(fn actor ->
-                   actor
-                   |> Events.list_event_participations_for_actor()
-                   |> participations_to_events()
-                 end)
-                 |> Enum.concat() do
-            {:ok,
-             %ICalendar{events: events |> Enum.map(&do_export_event/1)} |> ICalendar.to_ics()}
-          end
-      end
+      err ->
+        {:ignore, err}
     end
   end
 
-  defp participations_to_events(%Page{elements: participations}) do
-    participations
-    |> Enum.map(& &1.event_id)
-    |> Enum.map(&Events.get_event_with_preload!/1)
+  @spec fetch_instance_feed :: {:ok, String.t()}
+  defp fetch_instance_feed do
+    case Common.fetch_instance_public_content() do
+      {:ok, events, _posts} ->
+        {:ok, %ICalendar{events: events |> Enum.map(&do_export_event/1)} |> ICalendar.to_ics()}
+
+      err ->
+        {:error, err}
+    end
+  end
+
+  @doc """
+  Export an event to iCalendar format.
+  """
+  @spec export_event(Event.t()) :: {:ok, String.t()}
+  def export_event(%Event{} = event), do: {:ok, events_to_ics([event])}
+
+  @doc """
+  Export a public event to iCalendar format.
+
+  The event must have a visibility of `:public` or `:unlisted`
+  """
+  @spec export_public_event(Event.t()) :: {:ok, String.t()}
+  def export_public_event(%Event{visibility: visibility} = event)
+      when visibility in [:public, :unlisted] do
+    {:ok, events_to_ics([event])}
+  end
+
+  @spec export_public_event(Event.t()) :: {:error, :event_not_public}
+  def export_public_event(%Event{}), do: {:error, :event_not_public}
+
+  @doc """
+  Export a public actor's events to iCalendar format.
+
+  The actor must have a visibility of `:public` or `:unlisted`, as well as the events
+  """
+  @spec export_public_actor(String.t()) :: String.t()
+  def export_public_actor(name) do
+    case Common.fetch_actor_event_feed(name) do
+      {:ok, _actor, events, _posts} ->
+        {:ok, events_to_ics(events)}
+
+      err ->
+        {:error, err}
+    end
+  end
+
+  @spec export_private_actor(Actor.t()) :: String.t()
+  def export_private_actor(%Actor{} = actor) do
+    with events <- Common.fetch_actor_private_events(actor) do
+      {:ok, events_to_ics(events)}
+    end
+  end
+
+  @spec fetch_events_from_token(String.t()) :: String.t()
+  defp fetch_events_from_token(token) do
+    with %{events: events} <- Common.fetch_events_from_token(token) do
+      {:ok, events_to_ics(events)}
+    end
+  end
+
+  @spec events_to_ics(list(Events.t())) :: String.t()
+  defp events_to_ics(events) do
+    %ICalendar{events: events |> Enum.map(&do_export_event/1)}
+    |> ICalendar.to_ics(vendor: @vendor)
+  end
+
+  @spec do_export_event(Event.t()) :: ICalendar.Event.t()
+  defp do_export_event(%Event{} = event) do
+    %ICalendar.Event{
+      summary: event.title,
+      dtstart: event.begins_on,
+      dtstamp: event.publish_at || DateTime.utc_now(),
+      dtend: event.ends_on,
+      description: HTML.strip_tags(event.description),
+      uid: event.uuid,
+      url: event.url,
+      geo: Address.coords(event.physical_address),
+      location: Address.representation(event.physical_address),
+      categories: event.tags |> Enum.map(& &1.title)
+    }
   end
 end