WIP notification settings

Signed-off-by: Thomas Citharel <tcit@tcit.fr>

lib/service/activity/comment.ex

@@ -2,12 +2,12 @@ defmodule Mobilizon.Service.Activity.Comment do
   @moduledoc """
   Insert a comment activity
   """
-  alias Mobilizon.{Actors, Discussions, Events}
+  alias Mobilizon.{Discussions, Events}
   alias Mobilizon.Actors.Actor
   alias Mobilizon.Discussions.Comment
   alias Mobilizon.Events.Event
   alias Mobilizon.Service.Activity
-  alias Mobilizon.Service.Workers.ActivityBuilder
+  alias Mobilizon.Service.Workers.{ActivityBuilder, LegacyNotifierBuilder}
 
   @behaviour Activity
 
@@ -17,33 +17,21 @@ defmodule Mobilizon.Service.Activity.Comment do
   def insert_activity(
         %Comment{
           actor_id: actor_id,
-          event_id: event_id,
-          in_reply_to_comment_id: in_reply_to_comment_id
+          event_id: event_id
         } = comment,
         options
       )
       when not is_nil(actor_id) and not is_nil(event_id) do
-    with {:ok, %Event{attributed_to: %Actor{type: :Group} = group} = event} <-
-           Events.get_event_with_preload(event_id),
-         %Actor{id: actor_id} <- Actors.get_actor(actor_id),
-         subject <- Keyword.fetch!(options, :subject) do
-      ActivityBuilder.enqueue(:build_activity, %{
-        "type" => "event",
-        "subject" => subject,
-        "subject_params" => %{
-          event_title: event.title,
-          event_uuid: event.uuid,
-          comment_reply_to: !is_nil(in_reply_to_comment_id)
-        },
-        "group_id" => group.id,
-        "author_id" => actor_id,
-        "object_type" => "comment",
-        "object_id" => to_string(comment.id),
-        "inserted_at" => DateTime.utc_now()
-      })
-    else
-      # Event not from group
-      {:ok, %Event{}} -> {:ok, nil}
+    with {:ok, %Event{} = event} <-
+           Events.get_event_with_preload(event_id) do
+      # Notify the actors mentionned
+      notify_mentionned(comment, event)
+
+      # Notify participants if there's a new announcement
+      notify_announcement(comment, event)
+
+      # Notify event organizer or group that there's new comments
+      notify_organizer(comment, event, options)
     end
   end
 
@@ -53,4 +41,116 @@ defmodule Mobilizon.Service.Activity.Comment do
   def get_object(comment_id) do
     Discussions.get_comment(comment_id)
   end
+
+  defp notify_mentionned(%Comment{actor_id: actor_id, id: comment_id, mentions: mentions}, %Event{
+         uuid: uuid,
+         title: title
+       })
+       when length(mentions) > 0 do
+    LegacyNotifierBuilder.enqueue(:legacy_notify, %{
+      "type" => :comment,
+      "subject" => :event_comment_mention,
+      "subject_params" => %{
+        event_uuid: uuid,
+        event_title: title
+      },
+      "author_id" => actor_id,
+      "object_type" => :comment,
+      "object_id" => to_string(comment_id),
+      "inserted_at" => DateTime.utc_now(),
+      "mentions" => Enum.map(mentions, & &1.actor_id)
+    })
+  end
+
+  defp notify_mentionned(_, _), do: {:ok, :skipped}
+
+  defp notify_announcement(
+         %Comment{actor_id: actor_id, is_announcement: true, id: comment_id},
+         %Event{
+           id: event_id,
+           uuid: uuid,
+           title: title
+         }
+       ) do
+    LegacyNotifierBuilder.enqueue(:legacy_notify, %{
+      "type" => :comment,
+      "subject" => :participation_event_comment,
+      "subject_params" => %{
+        event_id: event_id,
+        event_uuid: uuid,
+        event_title: title
+      },
+      "author_id" => actor_id,
+      "object_type" => :comment,
+      "object_id" => to_string(comment_id),
+      "inserted_at" => DateTime.utc_now()
+    })
+  end
+
+  defp notify_announcement(_, _), do: {:ok, :skipped}
+
+  @spec notify_organizer(Comment.t(), Event.t(), Keyword.t()) ::
+          {:ok, Oban.Job.t()} | {:ok, :skipped}
+  defp notify_organizer(
+         %Comment{
+           actor_id: actor_id,
+           is_announcement: true,
+           in_reply_to_comment_id: in_reply_to_comment_id,
+           id: comment_id
+         },
+         %Event{
+           uuid: uuid,
+           title: title,
+           attributed_to: %Actor{type: :Group, id: group_id}
+         },
+         options
+       ) do
+    ActivityBuilder.enqueue(:build_activity, %{
+      "type" => "event",
+      "subject" => Keyword.fetch!(options, :subject),
+      "subject_params" => %{
+        event_title: title,
+        event_uuid: uuid,
+        comment_reply_to: !is_nil(in_reply_to_comment_id)
+      },
+      "group_id" => group_id,
+      "author_id" => actor_id,
+      "object_type" => "comment",
+      "object_id" => to_string(comment_id),
+      "inserted_at" => DateTime.utc_now()
+    })
+  end
+
+  defp notify_organizer(
+         %Comment{
+           actor_id: actor_id,
+           is_announcement: true,
+           in_reply_to_comment_id: in_reply_to_comment_id,
+           id: comment_id
+         },
+         %Event{
+           uuid: uuid,
+           title: title,
+           attributed_to: nil,
+           organizer_actor_id: organizer_actor_id
+         },
+         _options
+       )
+       when actor_id !== organizer_actor_id do
+    LegacyNotifierBuilder.enqueue(:legacy_notify, %{
+      "type" => :comment,
+      "subject" => :event_new_comment,
+      "subject_params" => %{
+        event_title: title,
+        event_uuid: uuid,
+        comment_reply_to: !is_nil(in_reply_to_comment_id)
+      },
+      "author_id" => actor_id,
+      "object_type" => :comment,
+      "object_id" => to_string(comment_id),
+      "inserted_at" => DateTime.utc_now()
+    })
+  end
+
+  defp notify_organizer(_, _, _), do: {:ok, :skipped}
 end

lib/service/activity/renderer/comment.ex

@@ -0,0 +1,111 @@
+defmodule Mobilizon.Service.Activity.Renderer.Comment do
+  @moduledoc """
+  Insert a comment activity
+  """
+  alias Mobilizon.Activities.Activity
+  alias Mobilizon.Actors.Actor
+  alias Mobilizon.Service.Activity.Renderer
+  alias Mobilizon.Web.{Endpoint, Gettext}
+  alias Mobilizon.Web.Router.Helpers, as: Routes
+  import Mobilizon.Web.Gettext, only: [dgettext: 3]
+
+  @behaviour Renderer
+
+  @impl Renderer
+  def render(%Activity{} = activity, options) do
+    locale = Keyword.get(options, :locale, "en")
+    Gettext.put_locale(locale)
+    profile = profile(activity)
+
+    case activity.subject do
+      :event_comment_mention ->
+        %{
+          body:
+            dgettext(
+              "activity",
+              "%{profile} mentionned you in a comment under event %{event}.",
+              %{
+                profile: profile,
+                event: event_title(activity)
+              }
+            ),
+          url: event_url(activity)
+        }
+
+      :participation_event_comment ->
+        %{
+          body:
+            dgettext(
+              "activity",
+              "%{profile} has posted an announcement under event %{event}.",
+              %{
+                profile: profile,
+                event: event_title(activity)
+              }
+            ),
+          url: event_url(activity)
+        }
+
+      :discussion_mention ->
+        %{
+          body:
+            dgettext("activity", "%{profile} mentionned you in the discussion %{discussion}.", %{
+              profile: profile,
+              discussion: title(activity)
+            }),
+          url: discussion_url(activity)
+        }
+
+      :discussion_renamed ->
+        %{
+          body:
+            dgettext("activity", "%{profile} renamed the discussion %{discussion}.", %{
+              profile: profile,
+              discussion: title(activity)
+            }),
+          url: discussion_url(activity)
+        }
+
+      :discussion_archived ->
+        %{
+          body:
+            dgettext("activity", "%{profile} archived the discussion %{discussion}.", %{
+              profile: profile,
+              discussion: title(activity)
+            }),
+          url: discussion_url(activity)
+        }
+
+      :discussion_deleted ->
+        %{
+          body:
+            dgettext("activity", "%{profile} deleted the discussion %{discussion}.", %{
+              profile: profile,
+              discussion: title(activity)
+            }),
+          url: nil
+        }
+    end
+  end
+
+  defp discussion_url(activity) do
+    Routes.page_url(
+      Endpoint,
+      :discussion,
+      Actor.preferred_username_and_domain(activity.group),
+      activity.subject_params["discussion_slug"]
+    )
+  end
+
+  defp event_url(activity) do
+    Routes.page_url(
+      Endpoint,
+      :event,
+      activity.subject_params["event_uuid"]
+    )
+  end
+
+  defp profile(activity), do: Actor.display_name_and_username(activity.author)
+  defp event_title(activity), do: activity.subject_params["event_title"]
+  defp title(activity), do: activity.subject_params["discussion_title"]
+end

lib/service/activity/renderer/renderer.ex

@@ -5,7 +5,17 @@ defmodule Mobilizon.Service.Activity.Renderer do
 
   alias Mobilizon.Config
   alias Mobilizon.Activities.Activity
-  alias Mobilizon.Service.Activity.Renderer.{Discussion, Event, Group, Member, Post, Resource}
+
+  alias Mobilizon.Service.Activity.Renderer.{
+    Comment,
+    Discussion,
+    Event,
+    Group,
+    Member,
+    Post,
+    Resource
+  }
+
   require Logger
   import Mobilizon.Web.Gettext, only: [dgettext: 3]
 
@@ -41,6 +51,7 @@ defmodule Mobilizon.Service.Activity.Renderer do
       :member -> Member.render(activity, options)
       :post -> Post.render(activity, options)
       :resource -> Resource.render(activity, options)
+      :comment -> Comment.render(activity, options)
       _ -> nil
     end
   end

lib/service/notifier/email.ex

@@ -5,7 +5,7 @@ defmodule Mobilizon.Service.Notifier.Email do
   alias Mobilizon.Activities.Activity
   alias Mobilizon.{Config, Users}
   alias Mobilizon.Service.Notifier
-  alias Mobilizon.Service.Notifier.Email
+  alias Mobilizon.Service.Notifier.{Email, Filter}
   alias Mobilizon.Users.{NotificationPendingNotificationDelay, Setting, User}
   alias Mobilizon.Web.Email.Activity, as: EmailActivity
   alias Mobilizon.Web.Email.Mailer
@@ -17,6 +17,8 @@ defmodule Mobilizon.Service.Notifier.Email do
     Config.get(__MODULE__, :enabled)
   end
 
+  def send(user, activity, options \\ [])
+
   @impl Notifier
   def send(%User{} = user, %Activity{} = activity, options) do
     Email.send(user, [activity], options)
@@ -25,7 +27,9 @@ defmodule Mobilizon.Service.Notifier.Email do
   @impl Notifier
   def send(%User{email: email, locale: locale} = user, activities, options)
       when is_list(activities) do
-    if can_send?(user) do
+    activities = Enum.filter(activities, &can_send_activity?(&1, user))
+
+    if can_send?(user) && length(activities) > 0 do
       email
       |> EmailActivity.direct_activity(activities, Keyword.put(options, :locale, locale))
       |> Mailer.send_email()
@@ -37,6 +41,34 @@ defmodule Mobilizon.Service.Notifier.Email do
     end
   end
 
+  @spec can_send_activity?(Activity.t(), User.t()) :: boolean()
+  defp can_send_activity?(%Activity{} = activity, %User{} = user) do
+    Filter.can_send_activity?(activity, "email", user, &default_activity_behavior/1)
+  end
+
+  @spec default_activity_behavior(String.t()) :: boolean()
+  defp default_activity_behavior(activity_setting) do
+    case activity_setting do
+      "participation_event_updated" -> true
+      "participation_event_comment" -> true
+      "event_new_pending_participation" -> true
+      "event_new_participation" -> false
+      "event_created" -> false
+      "event_updated" -> false
+      "discussion_updated" -> false
+      "post_published" -> false
+      "post_updated" -> false
+      "resource_updated" -> false
+      "member_request" -> true
+      "member_updated" -> false
+      "user_email_password_updated" -> true
+      "event_comment_mention" -> true
+      "discussion_mention" -> true
+      "event_new_comment" -> true
+      _ -> false
+    end
+  end
+
   @type notification_type ::
           :group_notifications
           | :notification_pending_participation

lib/service/notifier/filter.ex

@@ -0,0 +1,60 @@
+defmodule Mobilizon.Service.Notifier.Filter do
+  alias Mobilizon.Users
+  alias Mobilizon.Activities.Activity
+  alias Mobilizon.Users.{ActivitySetting, User}
+
+  @type method :: String.t()
+
+  @spec can_send_activity?(Activity.t(), method(), User.t(), function()) :: boolean()
+  def can_send_activity?(%Activity{} = activity, method, %User{} = user, get_default) do
+    case map_activity_to_activity_setting(activity) do
+      false -> false
+      key -> user |> Users.activity_setting(key, method) |> enabled?(key, get_default)
+    end
+  end
+
+  @spec enabled?(ActivitySetting.t() | nil, String.t(), function()) :: boolean()
+  defp enabled?(nil, activity_setting, get_default), do: get_default.(activity_setting)
+  defp enabled?(%ActivitySetting{enabled: enabled}, _activity_setting, _get_default), do: enabled
+
+  # Comment mention
+  defp map_activity_to_activity_setting(%Activity{subject: :event_comment_mention}),
+    do: "event_comment_mention"
+
+  # Participation
+  @spec map_activity_to_activity_setting(Activity.t()) :: String.t() | false
+  defp map_activity_to_activity_setting(%Activity{subject: :participation_event_updated}),
+    do: "participation_event_updated"
+
+  defp map_activity_to_activity_setting(%Activity{subject: :participation_event_comment}),
+    do: "participation_event_comment"
+
+  # Organizers
+  defp map_activity_to_activity_setting(%Activity{subject: :event_new_pending_participation}),
+    do: "event_new_pending_participation"
+
+  defp map_activity_to_activity_setting(%Activity{subject: :event_new_participation}),
+    do: "event_new_participation"
+
+  # Event
+  defp map_activity_to_activity_setting(%Activity{subject: :event_created}), do: "event_created"
+  defp map_activity_to_activity_setting(%Activity{type: :event}), do: "event_updated"
+
+  # Post
+  defp map_activity_to_activity_setting(%Activity{subject: :post_created}), do: "post_published"
+  defp map_activity_to_activity_setting(%Activity{type: :post}), do: "post_updated"
+
+  # Discussion
+  defp map_activity_to_activity_setting(%Activity{type: :discussion}), do: "discussion_updated"
+
+  # Resource
+  defp map_activity_to_activity_setting(%Activity{type: :resource}), do: "resource_updated"
+
+  # Member
+  defp map_activity_to_activity_setting(%Activity{subject: :member_request}),
+    do: "member_request"
+
+  defp map_activity_to_activity_setting(%Activity{type: :member}), do: "member"
+
+  defp map_activity_to_activity_setting(_), do: false
+end

lib/service/notifier/push.ex

@@ -6,7 +6,7 @@ defmodule Mobilizon.Service.Notifier.Push do
   alias Mobilizon.{Config, Users}
   alias Mobilizon.Service.Activity.{Renderer, Utils}
   alias Mobilizon.Service.Notifier
-  alias Mobilizon.Service.Notifier.Push
+  alias Mobilizon.Service.Notifier.{Filter, Push}
   alias Mobilizon.Storage.Page
   alias Mobilizon.Users.{PushSubscription, User}
 
@@ -20,11 +20,16 @@ defmodule Mobilizon.Service.Notifier.Push do
   @impl Notifier
   def send(user, activity, options \\ [])
 
-  def send(%User{id: user_id, locale: locale} = _user, %Activity{} = activity, options) do
-    options = Keyword.put_new(options, :locale, locale)
+  def send(%User{id: user_id, locale: locale} = user, %Activity{} = activity, options) do
+    if can_send_activity?(activity, user) do
+      options = Keyword.put_new(options, :locale, locale)
 
-    %Page{elements: subscriptions} = Users.list_user_push_subscriptions(user_id, 1, 100)
-    Enum.map(subscriptions, &send_subscription(activity, convert_subscription(&1), options))
+      %Page{elements: subscriptions} = Users.list_user_push_subscriptions(user_id, 1, 100)
+      Enum.each(subscriptions, &send_subscription(activity, convert_subscription(&1), options))
+      {:ok, :sent}
+    else
+      {:ok, :skipped}
+    end
   end
 
   @impl Notifier
@@ -32,6 +37,34 @@ defmodule Mobilizon.Service.Notifier.Push do
     Enum.map(activities, &Push.send(user, &1, options))
   end
 
+  @spec can_send_activity?(Activity.t(), User.t()) :: boolean()
+  defp can_send_activity?(%Activity{} = activity, %User{} = user) do
+    Filter.can_send_activity?(activity, "push", user, &default_activity_behavior/1)
+  end
+
+  @spec default_activity_behavior(String.t()) :: boolean()
+  defp default_activity_behavior(activity_setting) do
+    case activity_setting do
+      "participation_event_updated" -> true
+      "participation_event_comment" -> true
+      "event_new_pending_participation" -> true
+      "event_new_participation" -> false
+      "event_created" -> false
+      "event_updated" -> false
+      "discussion_updated" -> false
+      "post_published" -> false
+      "post_updated" -> false
+      "resource_updated" -> false
+      "member_request" -> true
+      "member_updated" -> false
+      "user_email_password_updated" -> false
+      "event_comment_mention" -> true
+      "discussion_mention" -> false
+      "event_new_comment" -> false
+      _ -> false
+    end
+  end
+
   defp send_subscription(activity, subscription, options) do
     activity
     |> payload(options)

lib/service/workers/legacy_notifier_builder.ex

@@ -0,0 +1,71 @@
+defmodule Mobilizon.Service.Workers.LegacyNotifierBuilder do
+  @moduledoc """
+  Worker to push legacy notifications
+  """
+
+  alias Mobilizon.{Actors, Events, Users}
+  alias Mobilizon.Activities.Activity
+  alias Mobilizon.Service.Notifier
+
+  use Mobilizon.Service.Workers.Helper, queue: "activity"
+
+  @impl Oban.Worker
+  def perform(%Job{args: args}) do
+    with {"legacy_notify", args} <- Map.pop(args, "op") do
+      activity = build_activity(args)
+
+      args
+      |> users_to_notify(args["author_id"])
+      |> Enum.each(&Notifier.notify(&1, activity, single_activity: true))
+    end
+  end
+
+  def build_activity(args) do
+    author = Actors.get_actor(args["author_id"])
+
+    %Activity{
+      type: String.to_existing_atom(args["type"]),
+      subject: String.to_existing_atom(args["subject"]),
+      subject_params: args["subject_params"],
+      inserted_at: DateTime.utc_now(),
+      object_type: String.to_existing_atom(args["object_type"]),
+      object_id: args["object_id"],
+      group: nil,
+      author: author
+    }
+  end
+
+  @spec users_to_notify(map(), integer() | String.t()) :: list(Users.t())
+  defp users_to_notify(
+         %{"subject" => "event_comment_mention", "mentions" => mentionned_actor_ids},
+         author_id
+       ) do
+    users_from_actor_ids(mentionned_actor_ids, author_id)
+  end
+
+  defp users_to_notify(
+         %{
+           "subject" => "participation_event_comment",
+           "subject_params" => subject_params
+         },
+         author_id
+       ) do
+    subject_params
+    |> Map.get("event_id")
+    |> Events.list_actors_participants_for_event()
+    |> Enum.map(& &1.id)
+    |> users_from_actor_ids(author_id)
+  end
+
+  @spec users_from_actor_ids(list(), integer() | String.t()) :: list(Users.t())
+  defp users_from_actor_ids(actor_ids, author_id) do
+    actor_ids
+    |> Enum.filter(&(&1 != author_id))
+    |> Enum.map(&Actors.get_actor/1)
+    |> Enum.filter(& &1)
+    |> Enum.map(& &1.user_id)
+    |> Enum.filter(& &1)
+    |> Enum.uniq()
+    |> Enum.map(&Users.get_user_with_settings!/1)
+  end
+end