Merge branch 'feature/add-pelias-geocoder' into 'master'

Feature/add pelias geocoder

See merge request framasoft/mobilizon!324

lib/service/geospatial/pelias.ex

@@ -0,0 +1,128 @@
+defmodule Mobilizon.Service.Geospatial.Pelias do
+  @moduledoc """
+  [Pelias](https://pelias.io) backend.
+
+  Doesn't provide type of POI.
+  """
+
+  alias Mobilizon.Addresses.Address
+  alias Mobilizon.Service.Geospatial.Provider
+  alias Mobilizon.Config
+
+  require Logger
+
+  @behaviour Provider
+
+  @endpoint Application.get_env(:mobilizon, __MODULE__) |> get_in([:endpoint])
+
+  @impl Provider
+  @doc """
+  Pelias implementation for `c:Mobilizon.Service.Geospatial.Provider.geocode/3`.
+  """
+  @spec geocode(number(), number(), keyword()) :: list(Address.t())
+  def geocode(lon, lat, options \\ []) do
+    user_agent = Keyword.get(options, :user_agent, Config.instance_user_agent())
+    headers = [{"User-Agent", user_agent}]
+    url = build_url(:geocode, %{lon: lon, lat: lat}, options)
+    Logger.debug("Asking Pelias for reverse geocoding with #{url}")
+
+    with {:ok, %HTTPoison.Response{status_code: 200, body: body}} <-
+           HTTPoison.get(url, headers),
+         {:ok, %{"features" => features}} <- Poison.decode(body) do
+      process_data(features)
+    end
+  end
+
+  @impl Provider
+  @doc """
+  Pelias implementation for `c:Mobilizon.Service.Geospatial.Provider.search/2`.
+  """
+  @spec search(String.t(), keyword()) :: list(Address.t())
+  def search(q, options \\ []) do
+    user_agent = Keyword.get(options, :user_agent, Config.instance_user_agent())
+    headers = [{"User-Agent", user_agent}]
+    url = build_url(:search, %{q: q}, options)
+    Logger.debug("Asking Pelias for addresses with #{url}")
+
+    with {:ok, %HTTPoison.Response{status_code: 200, body: body}} <-
+           HTTPoison.get(url, headers),
+         {:ok, %{"features" => features}} <- Poison.decode(body) do
+      process_data(features)
+    end
+  end
+
+  @spec build_url(atom(), map(), list()) :: String.t()
+  defp build_url(method, args, options) do
+    limit = Keyword.get(options, :limit, 10)
+    lang = Keyword.get(options, :lang, "en")
+    coords = Keyword.get(options, :coords, nil)
+    endpoint = Keyword.get(options, :endpoint, @endpoint)
+    country_code = Keyword.get(options, :country_code)
+
+    url =
+      case method do
+        :search ->
+          url =
+            "#{endpoint}/v1/autocomplete?text=#{URI.encode(args.q)}&lang=#{lang}&size=#{limit}"
+
+          if is_nil(coords),
+            do: url,
+            else: url <> "&focus.point.lat=#{coords.lat}&focus.point.lon=#{coords.lon}"
+
+        :geocode ->
+          "#{endpoint}/v1/reverse?point.lon=#{args.lon}&point.lat=#{args.lat}"
+      end
+
+    if is_nil(country_code), do: url, else: "#{url}&boundary.country=#{country_code}"
+  end
+
+  defp process_data(features) do
+    features
+    |> Enum.map(fn %{
+                     "geometry" => %{"coordinates" => coordinates},
+                     "properties" => properties
+                   } ->
+      address = process_address(properties)
+      %Address{address | geom: Provider.coordinates(coordinates)}
+    end)
+  end
+
+  defp process_address(properties) do
+    %Address{
+      country: Map.get(properties, "country"),
+      locality: Map.get(properties, "locality"),
+      region: Map.get(properties, "region"),
+      description: Map.get(properties, "name"),
+      postal_code: Map.get(properties, "postalcode"),
+      street: street_address(properties),
+      origin_id: "pelias:#{Map.get(properties, "id")}",
+      type: get_type(properties)
+    }
+  end
+
+  defp street_address(properties) do
+    if Map.has_key?(properties, "housenumber") do
+      "#{Map.get(properties, "housenumber")} #{Map.get(properties, "street")}"
+    else
+      Map.get(properties, "street")
+    end
+  end
+
+  @administrative_layers [
+    "neighbourhood",
+    "borough",
+    "localadmin",
+    "locality",
+    "county",
+    "macrocounty",
+    "region",
+    "macroregion",
+    "dependency"
+  ]
+
+  defp get_type(%{"layer" => layer}) when layer in @administrative_layers, do: "administrative"
+  defp get_type(%{"layer" => "address"}), do: "house"
+  defp get_type(%{"layer" => "street"}), do: "street"
+  defp get_type(%{"layer" => "venue"}), do: "venue"
+  defp get_type(%{"layer" => _}), do: nil
+end

lib/service/geospatial/provider.ex

@@ -9,11 +9,13 @@ defmodule Mobilizon.Service.Geospatial.Provider do
   * `Mobilizon.Service.Geospatial.Addok` [🔗](https://github.com/addok/addok)
   * `Mobilizon.Service.Geospatial.MapQuest` [🔗](https://developer.mapquest.com/documentation/open/)
   * `Mobilizon.Service.Geospatial.GoogleMaps` [🔗](https://developers.google.com/maps/documentation/geocoding/intro)
+  * `Mobilizon.Service.Geospatial.Mimirsbrunn` [🔗](https://github.com/CanalTP/mimirsbrunn)
+  * `Mobilizon.Service.Geospatial.Pelias` [🔗](https://pelias.io)
 
 
   ## Shared options
 
-  * `:user_agent` User-Agent string to send to the backend. Defaults to `"Mobilizon"`
+  * `:user_agent` User-Agent string to send to the backend. Defaults to `"Mobilizon"` or `Mobilizon.Config.instance_user_agent/0`
   * `:lang` Lang in which to prefer results. Used as a request parameter or
     through an `Accept-Language` HTTP header. Defaults to `"en"`.
   * `:country_code` An ISO 3166 country code. String or `nil`
@@ -31,7 +33,10 @@ defmodule Mobilizon.Service.Geospatial.Provider do
 
   ## Options
 
-  Most backends implement all of [the shared options](#module-shared-options).
+  In addition to [the shared options](#module-shared-options), `c:geocode/3` also
+  accepts the following options:
+
+  * `zoom` Level of detail required for the address. Default: 15
 
   ## Examples