Rename MobilizonWeb to Mobilizon.Web

test/web/controllers/activity_pub_controller_test.exs

@@ -0,0 +1,359 @@
+# Portions of this file are derived from Pleroma:
+# Copyright © 2017-2018 Pleroma Authors <https://pleroma.social>
+# SPDX-License-Identifier: AGPL-3.0-only
+# Upstream: https://git.pleroma.social/pleroma/pleroma/blob/develop/test/web/web_finger/web_finger_controller_test.exs
+
+defmodule Mobilizon.Web.ActivityPubControllerTest do
+  use ExVCR.Mock, adapter: ExVCR.Adapter.Hackney
+
+  use Mobilizon.Web.ConnCase
+
+  import Mobilizon.Factory
+
+  alias Mobilizon.{Actors, Config}
+  alias Mobilizon.Actors.Actor
+
+  alias Mobilizon.Federation.ActivityPub
+
+  alias Mobilizon.Web.ActivityPub.ActorView
+  alias Mobilizon.Web.Endpoint
+  alias Mobilizon.Web.PageView
+  alias Mobilizon.Web.Router.Helpers, as: Routes
+
+  setup_all do
+    Mobilizon.Config.put([:instance, :federating], true)
+    :ok
+  end
+
+  setup do
+    conn = build_conn() |> put_req_header("accept", "application/activity+json")
+    {:ok, conn: conn}
+  end
+
+  describe "/@:preferred_username" do
+    test "it returns a json representation of the actor", %{conn: conn} do
+      actor = insert(:actor)
+
+      conn =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :page))
+
+      actor = Actors.get_actor!(actor.id)
+
+      assert json_response(conn, 200) ==
+               ActorView.render("actor.json", %{actor: actor})
+               |> Jason.encode!()
+               |> Jason.decode!()
+    end
+  end
+
+  describe "/events/:uuid" do
+    test "it returns a json representation of the event", %{conn: conn} do
+      event = insert(:event)
+
+      conn =
+        conn
+        |> get(Routes.page_url(Endpoint, :event, event.uuid))
+
+      assert json_response(conn, 200) ==
+               PageView.render("event.activity-json", %{conn: %{assigns: %{object: event}}})
+    end
+
+    test "it returns 404 for non-public events", %{conn: conn} do
+      event = insert(:event, visibility: :private)
+
+      conn =
+        conn
+        |> put_req_header("accept", "application/activity+json")
+        |> get(Routes.page_url(Endpoint, :event, event.uuid))
+
+      assert json_response(conn, 404)
+    end
+  end
+
+  describe "/comments/:uuid" do
+    test "it returns a json representation of the comment", %{conn: conn} do
+      comment = insert(:comment)
+
+      conn =
+        conn
+        |> put_req_header("accept", "application/activity+json")
+        |> get(Routes.page_url(Endpoint, :comment, comment.uuid))
+
+      assert json_response(conn, 200) ==
+               PageView.render("comment.activity-json", %{conn: %{assigns: %{object: comment}}})
+    end
+
+    test "it returns 404 for non-public comments", %{conn: conn} do
+      comment = insert(:comment, visibility: :private)
+
+      conn =
+        conn
+        |> put_req_header("accept", "application/activity+json")
+        |> get(Routes.page_url(Endpoint, :comment, comment.uuid))
+
+      assert json_response(conn, 404)
+    end
+  end
+
+  describe "/@:preferred_username/inbox" do
+    test "it inserts an incoming event into the database", %{conn: conn} do
+      use_cassette "activity_pub_controller/mastodon-post-activity_actor_call" do
+        data = File.read!("test/fixtures/mastodon-post-activity.json") |> Jason.decode!()
+
+        conn =
+          conn
+          |> assign(:valid_signature, true)
+          |> post("#{Mobilizon.Web.Endpoint.url()}/inbox", data)
+
+        assert "ok" == json_response(conn, 200)
+        :timer.sleep(500)
+        assert ActivityPub.fetch_object_from_url(data["object"]["id"])
+      end
+    end
+  end
+
+  describe "/@:preferred_username/outbox" do
+    test "it returns a note activity in a collection", %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+      comment = insert(:comment, actor: actor)
+
+      conn =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :outbox))
+
+      assert json_response(conn, 200)["totalItems"] == 1
+      assert json_response(conn, 200)["first"]["orderedItems"] == [comment.url]
+    end
+
+    test "it returns an event activity in a collection", %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+      event = insert(:event, organizer_actor: actor)
+
+      conn =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :outbox))
+
+      assert json_response(conn, 200)["totalItems"] == 1
+      assert json_response(conn, 200)["first"]["orderedItems"] == [event.url]
+    end
+
+    test "it works for more than 10 events", %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+
+      Enum.each(1..15, fn _ ->
+        insert(:event, organizer_actor: actor)
+      end)
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :outbox))
+        |> json_response(200)
+
+      assert length(result["first"]["orderedItems"]) == 10
+      assert result["totalItems"] == 15
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :outbox, page: 2))
+        |> json_response(200)
+
+      assert length(result["orderedItems"]) == 5
+    end
+
+    test "it returns an empty collection if the actor has private visibility", %{conn: conn} do
+      actor = insert(:actor, visibility: :private)
+      insert(:event, organizer_actor: actor)
+
+      conn =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :outbox))
+
+      assert json_response(conn, 200)["totalItems"] == 0
+      assert json_response(conn, 200)["first"]["orderedItems"] == []
+    end
+
+    test "it doesn't returns an event activity in a collection if actor has private visibility",
+         %{conn: conn} do
+      actor = insert(:actor, visibility: :private)
+      insert(:event, organizer_actor: actor)
+
+      conn =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :outbox))
+
+      assert json_response(conn, 200)["totalItems"] == 0
+    end
+  end
+
+  describe "/@actor/followers" do
+    test "it returns the followers in a collection", %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+      actor2 = insert(:actor)
+      Actors.follow(actor, actor2)
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :followers))
+        |> json_response(200)
+
+      assert result["first"]["orderedItems"] == [actor2.url]
+    end
+
+    test "it returns no followers for a private actor", %{conn: conn} do
+      actor = insert(:actor, visibility: :private)
+      actor2 = insert(:actor)
+      Actors.follow(actor, actor2)
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :followers))
+        |> json_response(200)
+
+      assert result["first"]["orderedItems"] == []
+    end
+
+    test "it works for more than 10 actors", %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+
+      Enum.each(1..15, fn _ ->
+        other_actor = insert(:actor)
+        Actors.follow(actor, other_actor)
+      end)
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :followers))
+        |> json_response(200)
+
+      assert length(result["first"]["orderedItems"]) == 10
+      assert result["totalItems"] == 15
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :followers, page: 2))
+        |> json_response(200)
+
+      assert length(result["orderedItems"]) == 5
+    end
+  end
+
+  describe "/@actor/following" do
+    test "it returns the followings in a collection", %{conn: conn} do
+      actor = insert(:actor)
+      actor2 = insert(:actor, visibility: :public)
+      Actors.follow(actor, actor2)
+
+      result =
+        conn
+        |> get(Actor.build_url(actor2.preferred_username, :following))
+        |> json_response(200)
+
+      assert result["first"]["orderedItems"] == [actor.url]
+    end
+
+    test "it returns no followings for a private actor", %{conn: conn} do
+      actor = insert(:actor)
+      actor2 = insert(:actor, visibility: :private)
+      Actors.follow(actor, actor2)
+
+      result =
+        conn
+        |> get(Actor.build_url(actor2.preferred_username, :following))
+        |> json_response(200)
+
+      assert result["first"]["orderedItems"] == []
+    end
+
+    test "it works for more than 10 actors", %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+
+      Enum.each(1..15, fn _ ->
+        other_actor = insert(:actor)
+        Actors.follow(other_actor, actor)
+      end)
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :following))
+        |> json_response(200)
+
+      assert length(result["first"]["orderedItems"]) == 10
+      #  assert result["first"]["totalItems"] == 15
+      #  assert result["totalItems"] == 15
+
+      result =
+        conn
+        |> get(Actor.build_url(actor.preferred_username, :following, page: 2))
+        |> json_response(200)
+
+      assert length(result["orderedItems"]) == 5
+      #  assert result["totalItems"] == 15
+    end
+  end
+
+  describe "/relay" do
+    test "with the relay active, it returns the relay user", %{conn: conn} do
+      res =
+        conn
+        |> get(activity_pub_path(conn, :relay))
+        |> json_response(200)
+
+      assert res["id"] =~ "/relay"
+    end
+
+    test "with the relay disabled, it returns 404", %{conn: conn} do
+      Config.put([:instance, :allow_relay], false)
+
+      conn
+      |> get(activity_pub_path(conn, :relay))
+      |> json_response(404)
+      |> assert
+
+      Config.put([:instance, :allow_relay], true)
+    end
+  end
+
+  #
+  #  describe "/@:preferred_username/following" do
+  #    test "it returns the following in a collection", %{conn: conn} do
+  #      actor = insert(:actor)
+  #      actor2 = insert(:actor)
+  #      Mobilizon.Federation.ActivityPub.follow(actor, actor2)
+
+  #      result =
+  #        conn
+  #        |> get("/@#{actor.preferred_username}/following")
+  #        |> json_response(200)
+
+  #      assert result["first"]["orderedItems"] == [actor2.url]
+  #    end
+
+  #    test "it works for more than 10 actors", %{conn: conn} do
+  #      actor = insert(:actor)
+
+  #      Enum.each(1..15, fn _ ->
+  #        actor = Repo.get(Actor, actor.id)
+  #        other_actor = insert(:actor)
+  #        Actors.follow(actor, other_actor)
+  #      end)
+
+  #      result =
+  #        conn
+  #        |> get("/@#{actor.preferred_username}/following")
+  #        |> json_response(200)
+
+  #      assert length(result["first"]["orderedItems"]) == 10
+  #      assert result["first"]["totalItems"] == 15
+  #      assert result["totalItems"] == 15
+
+  #      result =
+  #        conn
+  #        |> get("/@#{actor.preferred_username}/following?page=2")
+  #        |> json_response(200)
+
+  #      assert length(result["orderedItems"]) == 5
+  #      assert result["totalItems"] == 15
+  #    end
+  #  end
+end

test/web/controllers/feed_controller_test.exs

@@ -0,0 +1,345 @@
+defmodule Mobilizon.Web.FeedControllerTest do
+  use Mobilizon.Web.ConnCase
+
+  import Mobilizon.Factory
+
+  alias Mobilizon.Web.Endpoint
+  alias Mobilizon.Web.Router.Helpers, as: Routes
+
+  describe "/@:preferred_username/feed/atom" do
+    test "it returns an RSS representation of the actor's public events if the actor is publicly visible",
+         %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+      tag1 = insert(:tag, title: "RSS", slug: "rss")
+      tag2 = insert(:tag, title: "ATOM", slug: "atom")
+      event1 = insert(:event, organizer_actor: actor, tags: [tag1])
+      event2 = insert(:event, organizer_actor: actor, tags: [tag1, tag2])
+
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:actor, actor.preferred_username, "atom")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "<?xml version=\"1.0\" encoding=\"UTF-8\"?>"
+      assert response_content_type(conn, :xml) =~ "charset=utf-8"
+
+      {:ok, feed} = ElixirFeedParser.parse(conn.resp_body)
+
+      assert feed.title == actor.preferred_username <> "'s public events feed on Mobilizon"
+
+      [entry1, entry2] = entries = feed.entries
+
+      Enum.each(entries, fn entry ->
+        assert entry.title in [event1.title, event2.title]
+      end)
+
+      # It seems categories takes term instead of Label
+      # <category label=\"RSS\" term=\"rss\"/>
+      assert entry1.categories == [tag2.title, tag1.title] |> Enum.map(&String.downcase/1)
+      assert entry2.categories == [tag1.title] |> Enum.map(&String.downcase/1)
+    end
+
+    test "it returns a 404 for the actor's public events Atom feed if the actor is not publicly visible",
+         %{conn: conn} do
+      actor = insert(:actor)
+      tag1 = insert(:tag, title: "RSS", slug: "rss")
+      tag2 = insert(:tag, title: "ATOM", slug: "atom")
+      insert(:event, organizer_actor: actor, tags: [tag1])
+      insert(:event, organizer_actor: actor, tags: [tag1, tag2])
+
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:actor, actor.preferred_username, "atom")
+          |> URI.decode()
+        )
+
+      assert response(conn, 404)
+    end
+
+    test "it returns an RSS representation of the actor's public events with the proper accept header",
+         %{conn: conn} do
+      actor = insert(:actor, visibility: :unlisted)
+
+      conn =
+        conn
+        |> put_req_header("accept", "application/atom+xml")
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:actor, actor.preferred_username, "atom")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "<?xml version=\"1.0\" encoding=\"UTF-8\"?>"
+      assert response_content_type(conn, :xml) =~ "charset=utf-8"
+    end
+
+    test "it doesn't return anything for an not existing actor", %{conn: conn} do
+      conn =
+        conn
+        |> put_req_header("accept", "application/atom+xml")
+        |> get("/@notexistent/feed/atom")
+
+      assert response(conn, 404)
+    end
+  end
+
+  describe "/@:preferred_username/feed/ics" do
+    test "it returns an iCalendar representation of the actor's public events with an actor publicly visible",
+         %{conn: conn} do
+      actor = insert(:actor, visibility: :public)
+      tag1 = insert(:tag, title: "iCalendar", slug: "icalendar")
+      tag2 = insert(:tag, title: "Apple", slug: "apple")
+      event1 = insert(:event, organizer_actor: actor, tags: [tag1])
+      event2 = insert(:event, organizer_actor: actor, tags: [tag1, tag2])
+
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:actor, actor.preferred_username, "ics")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "BEGIN:VCALENDAR"
+      assert response_content_type(conn, :calendar) =~ "charset=utf-8"
+
+      [entry1, entry2] = entries = ExIcal.parse(conn.resp_body)
+
+      Enum.each(entries, fn entry ->
+        assert entry.summary in [event1.title, event2.title]
+      end)
+
+      assert entry1.categories == [tag1.title]
+      assert entry2.categories == [tag1.title, tag2.title]
+    end
+
+    test "it returns a 404 page for the actor's public events iCal feed with an actor not publicly visible",
+         %{conn: conn} do
+      actor = insert(:actor, visibility: :private)
+      tag1 = insert(:tag, title: "iCalendar", slug: "icalendar")
+      tag2 = insert(:tag, title: "Apple", slug: "apple")
+      insert(:event, organizer_actor: actor, tags: [tag1])
+      insert(:event, organizer_actor: actor, tags: [tag1, tag2])
+
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:actor, actor.preferred_username, "ics")
+          |> URI.decode()
+        )
+
+      assert response(conn, 404)
+    end
+
+    test "it returns an iCalendar representation of the actor's public events with the proper accept header",
+         %{conn: conn} do
+      actor = insert(:actor, visibility: :unlisted)
+
+      conn =
+        conn
+        |> put_req_header("accept", "text/calendar")
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:actor, actor.preferred_username, "ics")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "BEGIN:VCALENDAR"
+      assert response_content_type(conn, :calendar) =~ "charset=utf-8"
+    end
+
+    test "it doesn't return anything for an not existing actor", %{conn: conn} do
+      conn =
+        conn
+        |> put_req_header("accept", "text/calendar")
+        |> get("/@notexistent/feed/ics")
+
+      assert response(conn, 404)
+    end
+  end
+
+  describe "/events/:uuid/export/ics" do
+    test "it returns an iCalendar representation of the event", %{conn: conn} do
+      tag1 = insert(:tag, title: "iCalendar", slug: "icalendar")
+      tag2 = insert(:tag, title: "Apple", slug: "apple")
+      event1 = insert(:event, tags: [tag1, tag2])
+
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:event, event1.uuid, "ics")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "BEGIN:VCALENDAR"
+      assert response_content_type(conn, :calendar) =~ "charset=utf-8"
+
+      [entry1] = ExIcal.parse(conn.resp_body)
+
+      assert entry1.summary == event1.title
+
+      assert entry1.categories == [tag1.title, tag2.title]
+    end
+  end
+
+  describe "/events/going/:token/atom" do
+    test "it returns an atom feed of all events for all identities for an user token", %{
+      conn: conn
+    } do
+      user = insert(:user)
+      actor1 = insert(:actor, user: user)
+      actor2 = insert(:actor, user: user)
+      event1 = insert(:event)
+      event2 = insert(:event)
+      insert(:participant, event: event1, actor: actor1)
+      insert(:participant, event: event2, actor: actor2)
+      feed_token = insert(:feed_token, user: user, actor: nil)
+
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:going, feed_token.token, "atom")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "<?xml version=\"1.0\" encoding=\"UTF-8\"?>"
+      assert response_content_type(conn, :xml) =~ "charset=utf-8"
+
+      {:ok, feed} = ElixirFeedParser.parse(conn.resp_body)
+
+      assert feed.title == "Feed for #{user.email} on Mobilizon"
+
+      entries = feed.entries
+
+      Enum.each(entries, fn entry ->
+        assert entry.title in [event1.title, event2.title]
+      end)
+    end
+
+    test "it returns an atom feed of all events a single identity for an actor token", %{
+      conn: conn
+    } do
+      user = insert(:user)
+      actor1 = insert(:actor, user: user)
+      actor2 = insert(:actor, user: user)
+      event1 = insert(:event)
+      event2 = insert(:event)
+      insert(:participant, event: event1, actor: actor1)
+      insert(:participant, event: event2, actor: actor2)
+      feed_token = insert(:feed_token, user: user, actor: actor1)
+
+      conn =
+        conn
+        |> put_req_header("accept", "application/atom+xml")
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:going, feed_token.token, "atom")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "<?xml version=\"1.0\" encoding=\"UTF-8\"?>"
+      assert response_content_type(conn, :xml) =~ "charset=utf-8"
+
+      {:ok, feed} = ElixirFeedParser.parse(conn.resp_body)
+
+      assert feed.title == "#{actor1.preferred_username}'s private events feed on Mobilizon"
+
+      [entry] = feed.entries
+      assert entry.title == event1.title
+    end
+
+    test "it returns 404 for an not existing feed", %{conn: conn} do
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:going, "not existing", "atom")
+          |> URI.decode()
+        )
+
+      assert response(conn, 404)
+    end
+  end
+
+  describe "/events/going/:token/ics" do
+    test "it returns an ical feed of all events for all identities for an user token", %{
+      conn: conn
+    } do
+      user = insert(:user)
+      actor1 = insert(:actor, user: user)
+      actor2 = insert(:actor, user: user)
+      event1 = insert(:event)
+      event2 = insert(:event)
+      insert(:participant, event: event1, actor: actor1)
+      insert(:participant, event: event2, actor: actor2)
+      feed_token = insert(:feed_token, user: user, actor: nil)
+
+      conn =
+        conn
+        |> put_req_header("accept", "text/calendar")
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:going, feed_token.token, "ics")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "BEGIN:VCALENDAR"
+      assert response_content_type(conn, :calendar) =~ "charset=utf-8"
+
+      entries = ExIcal.parse(conn.resp_body)
+
+      Enum.each(entries, fn entry ->
+        assert entry.summary in [event1.title, event2.title]
+      end)
+    end
+
+    test "it returns an ical feed of all events a single identity for an actor token", %{
+      conn: conn
+    } do
+      user = insert(:user)
+      actor1 = insert(:actor, user: user)
+      actor2 = insert(:actor, user: user)
+      event1 = insert(:event)
+      event2 = insert(:event)
+      insert(:participant, event: event1, actor: actor1)
+      insert(:participant, event: event2, actor: actor2)
+      feed_token = insert(:feed_token, user: user, actor: actor1)
+
+      conn =
+        conn
+        |> put_req_header("accept", "text/calendar")
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:going, feed_token.token, "ics")
+          |> URI.decode()
+        )
+
+      assert response(conn, 200) =~ "BEGIN:VCALENDAR"
+      assert response_content_type(conn, :calendar) =~ "charset=utf-8"
+
+      [entry1] = ExIcal.parse(conn.resp_body)
+      assert entry1.summary == event1.title
+      assert entry1.categories == event1.tags |> Enum.map(& &1.title)
+    end
+
+    test "it returns 404 for an not existing feed", %{conn: conn} do
+      conn =
+        conn
+        |> get(
+          Endpoint
+          |> Routes.feed_url(:going, "not existing", "ics")
+          |> URI.decode()
+        )
+
+      assert response(conn, 404)
+    end
+  end
+end

test/web/controllers/nodeinfo_controller_test.exs

@@ -0,0 +1,55 @@
+defmodule Mobilizon.Web.NodeInfoControllerTest do
+  use Mobilizon.Web.ConnCase
+
+  alias Mobilizon.Config
+
+  alias Mobilizon.Web.Endpoint
+  alias Mobilizon.Web.Router.Helpers, as: Routes
+
+  test "Get node info schemas", %{conn: conn} do
+    conn = get(conn, node_info_path(conn, :schemas))
+
+    assert json_response(conn, 200) == %{
+             "links" => [
+               %{
+                 "href" => Routes.node_info_url(Endpoint, :nodeinfo, "2.0"),
+                 "rel" => "http://nodeinfo.diaspora.software/ns/schema/2.0"
+               },
+               %{
+                 "href" => Routes.node_info_url(Endpoint, :nodeinfo, "2.1"),
+                 "rel" => "http://nodeinfo.diaspora.software/ns/schema/2.1"
+               }
+             ]
+           }
+  end
+
+  test "Get node info", %{conn: conn} do
+    # We clear the cache because it might have been initialized by other tests
+    Cachex.clear(:statistics)
+    conn = get(conn, node_info_path(conn, :nodeinfo, "2.1"))
+    resp = json_response(conn, 200)
+
+    assert resp == %{
+             "metadata" => %{
+               "nodeName" => Config.instance_name(),
+               "nodeDescription" => Config.instance_description()
+             },
+             "openRegistrations" => Config.instance_registrations_open?(),
+             "protocols" => ["activitypub"],
+             "services" => %{"inbound" => [], "outbound" => ["atom1.0"]},
+             "software" => %{
+               "name" => "Mobilizon",
+               "version" => Config.instance_version(),
+               "repository" => Config.instance_repository()
+             },
+             "usage" => %{"localComments" => 0, "localPosts" => 0, "users" => %{"total" => 0}},
+             "version" => "2.1"
+           }
+  end
+
+  test "Get node info with non supported version (1.0)", %{conn: conn} do
+    conn = get(conn, node_info_path(conn, :nodeinfo, "1.0"))
+
+    assert json_response(conn, 404) == %{"error" => "Nodeinfo schema version not handled"}
+  end
+end

test/web/controllers/page_controller_test.exs

@@ -0,0 +1,65 @@
+defmodule Mobilizon.Web.PageControllerTest do
+  use Mobilizon.Web.ConnCase
+
+  import Mobilizon.Factory
+
+  alias Mobilizon.Actors.Actor
+
+  alias Mobilizon.Web.Endpoint
+  alias Mobilizon.Web.Router.Helpers, as: Routes
+
+  setup do
+    conn = build_conn() |> put_req_header("accept", "text/html")
+    {:ok, conn: conn}
+  end
+
+  test "GET /", %{conn: conn} do
+    conn = get(conn, "/")
+    assert html_response(conn, 200)
+  end
+
+  test "GET /@actor with existing actor", %{conn: conn} do
+    actor = insert(:actor)
+    conn = get(conn, Actor.build_url(actor.preferred_username, :page))
+    assert html_response(conn, 200) =~ actor.preferred_username
+  end
+
+  test "GET /@actor with not existing actor", %{conn: conn} do
+    conn = get(conn, Actor.build_url("not_existing", :page))
+    assert html_response(conn, 404)
+  end
+
+  test "GET /events/:uuid", %{conn: conn} do
+    event = insert(:event)
+    conn = get(conn, Routes.page_url(Endpoint, :event, event.uuid))
+    assert html_response(conn, 200) =~ event.title
+  end
+
+  test "GET /events/:uuid with not existing event", %{conn: conn} do
+    conn = get(conn, Routes.page_url(Endpoint, :event, "not_existing_event"))
+    assert html_response(conn, 404)
+  end
+
+  test "GET /events/:uuid with event not public", %{conn: conn} do
+    event = insert(:event, visibility: :restricted)
+    conn = get(conn, Routes.page_url(Endpoint, :event, event.uuid))
+    assert html_response(conn, 404)
+  end
+
+  test "GET /comments/:uuid", %{conn: conn} do
+    comment = insert(:comment)
+    conn = get(conn, Routes.page_url(Endpoint, :comment, comment.uuid))
+    assert html_response(conn, 200) =~ comment.text
+  end
+
+  test "GET /comments/:uuid with not existing comment", %{conn: conn} do
+    conn = get(conn, Routes.page_url(Endpoint, :comment, "not_existing_comment"))
+    assert html_response(conn, 404)
+  end
+
+  test "GET /comments/:uuid with comment not public", %{conn: conn} do
+    comment = insert(:comment, visibility: :private)
+    conn = get(conn, Routes.page_url(Endpoint, :comment, comment.uuid))
+    assert html_response(conn, 404)
+  end
+end

test/web/controllers/webfinger_controller_test.exs

@@ -0,0 +1,46 @@
+# Portions of this file are derived from Pleroma:
+# Copyright © 2017-2018 Pleroma Authors <https://pleroma.social>
+# SPDX-License-Identifier: AGPL-3.0-only
+# Upstream: https://git.pleroma.social/pleroma/pleroma/blob/develop/test/web/web_finger/web_finger_test.exs
+
+defmodule Mobilizon.Web.WebFingerControllerTest do
+  use Mobilizon.Web.ConnCase
+
+  import Mobilizon.Factory
+
+  alias Mobilizon.Actors.Actor
+  alias Mobilizon.Federation.WebFinger
+
+  setup_all do
+    Mobilizon.Config.put([:instance, :federating], true)
+
+    :ok
+  end
+
+  test "GET /.well-known/host-meta", %{conn: conn} do
+    conn = get(conn, "/.well-known/host-meta")
+
+    assert response(conn, 200) ==
+             "<?xml version=\"1.0\" encoding=\"UTF-8\"?><XRD xmlns=\"http://docs.oasis-open.org/ns/xri/xrd-1.0\"><Link rel=\"lrdd\" template=\"#{
+               Mobilizon.Web.Endpoint.url()
+             }/.well-known/webfinger?resource={uri}\" type=\"application/xrd+xml\" /></XRD>"
+
+    assert {"content-type", "application/xrd+xml; charset=utf-8"} in conn.resp_headers
+  end
+
+  test "GET /.well-known/webfinger with local actor", %{conn: conn} do
+    %Actor{preferred_username: username} = actor = insert(:actor)
+    conn = get(conn, "/.well-known/webfinger?resource=acct:#{username}@mobilizon.test")
+    assert json_response(conn, 200) == WebFinger.represent_actor(actor)
+  end
+
+  test "GET /.well-known/webfinger with non existent actor", %{conn: conn} do
+    conn = get(conn, "/.well-known/webfinger?resource=acct:notme@mobilizon.test")
+    assert response(conn, 404) == "Couldn't find user"
+  end
+
+  test "GET /.well-known/webfinger with no query", %{conn: conn} do
+    conn = get(conn, "/.well-known/webfinger")
+    assert response(conn, 400) == "No query provided"
+  end
+end