Fix issue when updating event and introduce background jobs

Signed-off-by: Thomas Citharel <tcit@tcit.fr>

lib/service/workers/build_search_worker.ex

@@ -0,0 +1,75 @@
+defmodule Mobilizon.Service.Workers.BuildSearchWorker do
+  @moduledoc """
+  Worker to build search results
+  """
+
+  alias Mobilizon.Events
+  alias Mobilizon.Events.Event
+  alias Mobilizon.Storage.Repo
+  alias Ecto.Adapters.SQL
+
+  use Mobilizon.Service.Workers.WorkerHelper, queue: "search"
+
+  @impl Oban.Worker
+  def perform(%{"op" => "insert_search_event", "event_id" => event_id}, _job) do
+    with {:ok, %Event{} = event} <- Events.get_event_with_preload(event_id) do
+      insert_search_event(event)
+    end
+  end
+
+  def perform(%{"op" => "update_search_event", "event_id" => event_id}, _job) do
+    with {:ok, %Event{} = event} <- Events.get_event_with_preload(event_id) do
+      update_search_event(event)
+    end
+  end
+
+  def insert_search_event(%Event{} = event) do
+    SQL.query(
+      Repo,
+      """
+        INSERT INTO event_search(id, title, document) VALUES ($1, $2, (
+          SELECT
+            setweight(to_tsvector(unaccent($2)), 'A') ||
+            setweight(to_tsvector(unaccent(coalesce($4, ' '))), 'B') ||
+            setweight(to_tsvector(unaccent($3)), 'C')
+          )
+        );
+      """,
+      [
+        event.id,
+        event.title,
+        HtmlSanitizeEx.strip_tags(event.description),
+        get_tags_string(event)
+      ]
+    )
+  end
+
+  def update_search_event(%Event{} = event) do
+    SQL.query(
+      Repo,
+      """
+        UPDATE event_search
+          SET document =
+            (SELECT
+              setweight(to_tsvector(unaccent($2)), 'A') ||
+              setweight(to_tsvector(unaccent(coalesce($4, ' '))), 'B') ||
+              setweight(to_tsvector(unaccent($3)), 'C')
+            ),
+          title = $2
+          WHERE id = $1;
+      """,
+      [
+        event.id,
+        event.title,
+        HtmlSanitizeEx.strip_tags(event.description),
+        get_tags_string(event)
+      ]
+    )
+  end
+
+  defp get_tags_string(%Event{tags: tags}) do
+    tags
+    |> Enum.map(& &1.title)
+    |> Enum.join(" ")
+  end
+end

lib/service/workers/worker_helper.ex

@@ -0,0 +1,50 @@
+# Portions of this file are derived from Pleroma:
+# Copyright © 2017-2019 Pleroma Authors <https://pleroma.social>
+# SPDX-License-Identifier: AGPL-3.0-only
+# Upstream: https://git.pleroma.social/pleroma/pleroma/blob/develop/lib/pleroma/workers/worker_helper.ex
+
+defmodule Mobilizon.Service.Workers.WorkerHelper do
+  @moduledoc """
+  Tools to ease dealing with workers
+  """
+  alias Mobilizon.Config
+  alias Mobilizon.Service.Workers.WorkerHelper
+
+  def worker_args(queue) do
+    case Config.get([:workers, :retries, queue]) do
+      nil -> []
+      max_attempts -> [max_attempts: max_attempts]
+    end
+  end
+
+  def sidekiq_backoff(attempt, pow \\ 4, base_backoff \\ 15) do
+    backoff =
+      :math.pow(attempt, pow) +
+        base_backoff +
+        :rand.uniform(2 * base_backoff) * attempt
+
+    trunc(backoff)
+  end
+
+  defmacro __using__(opts) do
+    caller_module = __CALLER__.module
+    queue = Keyword.fetch!(opts, :queue)
+
+    quote do
+      # Note: `max_attempts` is intended to be overridden in `new/2` call
+      use Oban.Worker,
+        queue: unquote(queue),
+        max_attempts: 1
+
+      def enqueue(operation, params, worker_args \\ []) do
+        params = Map.merge(%{"op" => operation}, params)
+        queue_atom = String.to_existing_atom(unquote(queue))
+        worker_args = worker_args ++ WorkerHelper.worker_args(queue_atom)
+
+        unquote(caller_module)
+        |> apply(:new, [params, worker_args])
+        |> Mobilizon.Storage.Repo.insert()
+      end
+    end
+  end
+end