Move Email context under MobilizonWeb

lib/mobilizon_web/email/admin.ex

@@ -0,0 +1,38 @@
+defmodule MobilizonWeb.Email.Admin do
+  @moduledoc """
+  Handles emails sent to admins.
+  """
+
+  use Bamboo.Phoenix, view: MobilizonWeb.EmailView
+
+  import Bamboo.{Email, Phoenix}
+
+  import MobilizonWeb.Gettext
+
+  alias Mobilizon.Config
+  alias Mobilizon.Reports.Report
+  alias Mobilizon.Users.User
+
+  alias MobilizonWeb.Email
+
+  @spec report(User.t(), Report.t(), String.t()) :: Bamboo.Email.t()
+  def report(%User{email: email}, %Report{} = report, locale \\ "en") do
+    Gettext.put_locale(locale)
+
+    instance_url = Config.instance_url()
+
+    subject =
+      gettext(
+        "Mobilizon: New report on instance %{instance}",
+        instance: instance_url
+      )
+
+    Email.base_email()
+    |> to(email)
+    |> subject(subject)
+    |> put_header("Reply-To", Config.instance_email_reply_to())
+    |> assign(:report, report)
+    |> assign(:instance, instance_url)
+    |> render(:report)
+  end
+end

lib/mobilizon_web/email/email.ex

@@ -0,0 +1,17 @@
+defmodule MobilizonWeb.Email do
+  @moduledoc """
+  The Email context.
+  """
+
+  use Bamboo.Phoenix, view: MobilizonWeb.EmailView
+
+  alias Mobilizon.Config
+
+  @spec base_email :: Bamboo.Email.t()
+  def base_email do
+    new_email()
+    |> from(Config.instance_email_from())
+    |> put_html_layout({MobilizonWeb.EmailView, "email.html"})
+    |> put_text_layout({MobilizonWeb.EmailView, "email.text"})
+  end
+end

lib/mobilizon_web/email/mailer.ex

@@ -0,0 +1,6 @@
+defmodule MobilizonWeb.Email.Mailer do
+  @moduledoc """
+  Mobilizon Mailer.
+  """
+  use Bamboo.Mailer, otp_app: :mobilizon
+end

lib/mobilizon_web/email/user.ex

@@ -0,0 +1,64 @@
+defmodule MobilizonWeb.Email.User do
+  @moduledoc """
+  Handles emails sent to users.
+  """
+
+  use Bamboo.Phoenix, view: MobilizonWeb.EmailView
+
+  import Bamboo.{Email, Phoenix}
+
+  import MobilizonWeb.Gettext
+
+  alias Mobilizon.Config
+  alias Mobilizon.Users.User
+
+  alias MobilizonWeb.Email
+
+  @spec confirmation_email(User.t(), String.t()) :: Bamboo.Email.t()
+  def confirmation_email(
+        %User{email: email, confirmation_token: confirmation_token},
+        locale \\ "en"
+      ) do
+    Gettext.put_locale(locale)
+
+    instance_url = Config.instance_url()
+
+    subject =
+      gettext(
+        "Mobilizon: Confirmation instructions for %{instance}",
+        instance: instance_url
+      )
+
+    Email.base_email()
+    |> to(email)
+    |> subject(subject)
+    |> put_header("Reply-To", Config.instance_email_reply_to())
+    |> assign(:token, confirmation_token)
+    |> assign(:instance, instance_url)
+    |> render(:registration_confirmation)
+  end
+
+  @spec reset_password_email(User.t(), String.t()) :: Bamboo.Email.t()
+  def reset_password_email(
+        %User{email: email, reset_password_token: reset_password_token},
+        locale \\ "en"
+      ) do
+    Gettext.put_locale(locale)
+
+    instance_url = Config.instance_url()
+
+    subject =
+      gettext(
+        "Mobilizon: Reset your password on %{instance} instructions",
+        instance: instance_url
+      )
+
+    Email.base_email()
+    |> to(email)
+    |> subject(subject)
+    |> put_header("Reply-To", Config.instance_email_reply_to())
+    |> assign(:token, reset_password_token)
+    |> assign(:instance, instance_url)
+    |> render(:password_reset)
+  end
+end

lib/mobilizon_web/views/email_view.ex

@@ -1,3 +1,3 @@
-defmodule Mobilizon.EmailView do
+defmodule MobilizonWeb.EmailView do
   use MobilizonWeb, :view
 end