Refactor media upload

Use Upload Media logic from Pleroma

Backend changes for picture upload

Move AS <-> Model conversion to separate module

Front changes

Downgrade apollo-client: https://github.com/Akryum/vue-apollo/issues/577

Signed-off-by: Thomas Citharel <tcit@tcit.fr>

lib/mobilizon_web/upload/filter.ex

@@ -0,0 +1,42 @@
+# Portions of this file are derived from Pleroma:
+# Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+# Upstream: https://git.pleroma.social/pleroma/pleroma/blob/develop/lib/pleroma/upload/filter.ex
+
+defmodule MobilizonWeb.Upload.Filter do
+  @moduledoc """
+  Upload Filter behaviour
+
+  This behaviour allows to run filtering actions just before a file is uploaded. This allows to:
+
+  * morph in place the temporary file
+  * change any field of a `Mobilizon.Upload` struct
+  * cancel/stop the upload
+  """
+
+  require Logger
+
+  @callback filter(MobilizonWeb.Upload.t()) ::
+              :ok | {:ok, MobilizonWeb.Upload.t()} | {:error, any()}
+
+  @spec filter([module()], MobilizonWeb.Upload.t()) ::
+          {:ok, MobilizonWeb.Upload.t()} | {:error, any()}
+
+  def filter([], upload) do
+    {:ok, upload}
+  end
+
+  def filter([filter | rest], upload) do
+    case filter.filter(upload) do
+      :ok ->
+        filter(rest, upload)
+
+      {:ok, upload} ->
+        filter(rest, upload)
+
+      error ->
+        Logger.error("#{__MODULE__}: Filter #{filter} failed: #{inspect(error)}")
+        error
+    end
+  end
+end

lib/mobilizon_web/upload/filter/anonymize_filename.ex

@@ -0,0 +1,28 @@
+# Portions of this file are derived from Pleroma:
+# Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+# Upstream: https://git.pleroma.social/pleroma/pleroma/blob/develop/lib/pleroma/upload/filter/anonymize_filename.ex
+
+defmodule MobilizonWeb.Upload.Filter.AnonymizeFilename do
+  @moduledoc """
+  Replaces the original filename with a pre-defined text or randomly generated string.
+
+  Should be used after `MobilizonWeb.Upload.Filter.Dedupe`.
+  """
+  @behaviour MobilizonWeb.Upload.Filter
+
+  def filter(upload) do
+    extension = List.last(String.split(upload.name, "."))
+    name = Mobilizon.CommonConfig.get([__MODULE__, :text], random(extension))
+    {:ok, %MobilizonWeb.Upload{upload | name: name}}
+  end
+
+  defp random(extension) do
+    string =
+      10
+      |> :crypto.strong_rand_bytes()
+      |> Base.url_encode64(padding: false)
+
+    string <> "." <> extension
+  end
+end

lib/mobilizon_web/upload/filter/dedupe.ex

@@ -0,0 +1,19 @@
+# Portions of this file are derived from Pleroma:
+# Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+# Upstream: https://git.pleroma.social/pleroma/pleroma/blob/develop/lib/pleroma/upload/filter/dedupe.ex
+
+defmodule MobilizonWeb.Upload.Filter.Dedupe do
+  @moduledoc """
+  Names the file after its hash to avoid dedupes
+  """
+  @behaviour MobilizonWeb.Upload.Filter
+  alias MobilizonWeb.Upload
+
+  def filter(%Upload{name: name} = upload) do
+    extension = String.split(name, ".") |> List.last()
+    shasum = :crypto.hash(:sha256, File.read!(upload.tempfile)) |> Base.encode16(case: :lower)
+    filename = shasum <> "." <> extension
+    {:ok, %Upload{upload | id: shasum, path: filename}}
+  end
+end

lib/mobilizon_web/upload/filter/mogrify.ex

@@ -0,0 +1,45 @@
+# Portions of this file are derived from Pleroma:
+# Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+# Upstream: https://git.pleroma.social/pleroma/pleroma/blob/develop/lib/pleroma/upload/filter/mogrify.ex
+
+defmodule MobilizonWeb.Upload.Filter.Mogrify do
+  @moduledoc """
+  Handle mogrify transformations
+  """
+  @behaviour MobilizonWeb.Upload.Filter
+
+  @type conversion :: action :: String.t() | {action :: String.t(), opts :: String.t()}
+  @type conversions :: conversion() | [conversion()]
+
+  def filter(%MobilizonWeb.Upload{tempfile: file, content_type: "image" <> _}) do
+    filters = Mobilizon.CommonConfig.get!([__MODULE__, :args])
+
+    file
+    |> Mogrify.open()
+    |> mogrify_filter(filters)
+    |> Mogrify.save(in_place: true)
+
+    :ok
+  end
+
+  def filter(_), do: :ok
+
+  defp mogrify_filter(mogrify, nil), do: mogrify
+
+  defp mogrify_filter(mogrify, [filter | rest]) do
+    mogrify
+    |> mogrify_filter(filter)
+    |> mogrify_filter(rest)
+  end
+
+  defp mogrify_filter(mogrify, []), do: mogrify
+
+  defp mogrify_filter(mogrify, {action, options}) do
+    Mogrify.custom(mogrify, action, options)
+  end
+
+  defp mogrify_filter(mogrify, action) when is_binary(action) do
+    Mogrify.custom(mogrify, action)
+  end
+end